#!/bin/csh
#
#  10 Apr 1993 - MWS
#
#  C-shell script to execute a GAMESS --production-- job.
#
#  This script executes a sequential-linked or a parallel-linked 
#  version of GAMESS in sequential mode only, so the full program 
#  functionality is available.   
#
#  The script is executed by any user by typing
#       gms JOB >& JOB.log &
#  where JOB is the name of the 'JOB.inp' file to be executed.
#
#  Each user needs an alias to point to this common script,
#  such as placing this line in their C shell .login file:
#       alias gms 'nice +15 /u/mike/gamess/seqgms'
#
#  The installer needs to 
#    a) choose a directory SCR where large temporary files can reside, 
#    b) set PARALLEL according to how GAMESS was linked, 
#    c) set the version number used when GAMESS was linked,
#    d) change the path variable to point to GAMESS -or- TCGMSG,
#    e) look at the locations of the PUNCH and IRCDATA files below,
#    f) change the path in the parallel execution section below.
#
#nice +15
set PROGDIR=/mit/10.610/bin/`machtype`bin
set PARALLEL=false
set VERNO=00
if ( ! $?SCR ) then
   set SCR=/usr/tmp
   echo 'Setting scratch directory to '$SCR
   echo 'To change use set SCR=<your_choice>'
else
   if( ! -e $SCR ) then
      set SCR=/usr/tmp
      echo 'Setting scratch directory to '$SCR
      echo 'To change use set SCR= <your_choice>'
   endif
endif
if( ! $?SAVEDIR ) then
   set SAVEDIR=.
   echo  'Save directory for punchfile is '$SAVEDIR
   echo 'Change variable SAVEDIR to change'
endif
echo "Scratch directory:  "$SCR
echo "Punch file in "$SAVEDIR
if ($PARALLEL == true) then
   set path=($path /mit/10.610/gamess/bin $PROGDIR)
else
   set path=($path /mit/10.610/gamess/bin $PROGDIR)
endif
#
set PARALLEL=false
#set VERNO=54
#if ($PARALLEL == true) then
#   set path=($path /u/mike/tcgmsg/ipcv4.0)
#else
#   set path=($path /u/mike/gamess)
#endif
#
set JOB=$1
set SCR1=$2    # these two args are specialized for disk config at ISU
set JOBTYPE=$3
#
echo This job is running on host `hostname`
date
echo ----- GAMESS execution script -----
set echo

#  Grab a copy of the input file.
cp   $JOB.inp  $SCR/$JOB.F05

#  file assignments.
setenv IRCDATA $SAVEDIR/$JOB.irc
setenv   INPUT $SCR/$JOB.F05
setenv   PUNCH $SAVEDIR/$JOB.dat
setenv  AOINTS $SCR/$JOB.F08
setenv  MOINTS $SCR/$JOB.F09
setenv DICTNRY $SCR/$JOB.F10
setenv DRTFILE $SCR/$JOB.F11
setenv CIVECTR $SCR/$JOB.F12
setenv NTNFMLA $SCR/$JOB.F13
setenv  CIINTS $SCR/$JOB.F14
setenv  WORK15 $SCR/$JOB.F15
setenv  WORK16 $SCR/$JOB.F16
setenv CSFSAVE $SCR/$JOB.F17
setenv FOCKDER $SCR/$JOB.F18
setenv  DASORT $SCR/$JOB.F20
setenv  JKFILE $SCR/$JOB.F23
setenv  ORDINT $SCR/$JOB.F24
setenv  EFPIND $SCR/$JOB.F25

#   now execute GAMESS.
#   A sequential mode .p file is built on the fly, if you
#   are using a parallel-linked version.  Its pathname may
#   need to be changed!
unset echo
if ($PARALLEL == true) then
   setenv PROCGRP $SCR/$JOB.p
   cat << ENDOFCAT > $PROCGRP
$USER `hostname` 1 /u/mike/gamess/gamess.$VERNO.x $SCR
ENDOFCAT
   set echo
   parallel  $JOB
   unset echo
   rm -f $PROCGRP
else
   set echo
   gamess.$VERNO.x   $JOB
   unset echo
endif

echo ----- accounting info -----
date
ls -lF $SCR/$JOB.*
rm -f  $SCR/$JOB.F*
time
exit